# $git add .
# $nix run
{
  inputs.utils.url = "github:numtide/flake-utils";
  inputs.gnome-info-collect.url = "git+https://gitlab.gnome.org/vstanek/gnome-info-collect";
  inputs.gnome-info-collect.flake = false;

  outputs = {
    self,
    nixpkgs,
    utils,
    gnome-info-collect,
  }: let
    out = system: let
      pkgs = nixpkgs.legacyPackages."${system}";
      buildInputs = with pkgs; [
        python3Packages.pygobject3
        python3Packages.pip
        python3Packages.requests
        gnome-online-accounts
        python3Packages.jsonschema
      ];
    in {
      devShell = pkgs.mkShell {
        inherit buildInputs;
      };

      packages.default =
        pkgs.writers.writePython3Bin "client"
        {libraries = buildInputs;} ''
          # flake8: noqa
          ${builtins.readFile (gnome-info-collect + "/client/client.py")}
        '';
      packages.server =
        pkgs.writers.writePython3Bin "server"
        {libraries = buildInputs;} ''
          # flake8: noqa
          ${builtins.readFile (gnome-info-collect + "/server/server.py")}
        '';

      apps.default = utils.lib.mkApp {
        drv = self.packages."${system}".default;
      };
      apps.server = utils.lib.mkApp {
        drv = self.packages."${system}".server;
      };
    };
  in
    with utils.lib; eachSystem defaultSystems out;
}